# @(#)Login 1.14 90/11/01 SMI
##################################################################
#
#         .login file
#
#         Read in after the .cshrc file when you log in.
#         Not read in for subsequent shells.  For setting up
#         terminal and global environment characteristics.
#
##################################################################
#
#	8/27/98: prohibit core dump files
#	8/25/98: select java version based on JAVA_HOME
#
#	6/21/96:
#	Determine OS type, i.e., is this a Solaris machine
#	or a SunOS machine.  To do this use the use the
#	command "uname -r" to get the release number of
# 	the OS. This will give numbers like 4.3.1 or 5.3.
#	Take the "root" of this value twice to get either
# 	4 (for SunOS) or 5 (for Solaris), and set the
#	OS variable accordingly.

	set OS=`/usr/bin/uname -r`
	set OS=${OS:r}
	set OS=${OS:r}
	if($OS == "4") then
		set OS = "SunOS"
	else
		set OS = "Solaris"
	endif

#prohibit core dump files
limit coredumpsize 0

#         general terminal characteristics

#stty -tabs
#stty crt
stty erase '^h'
#stty erase '^?'
#stty kill '^['

#         environment variables
setenv CLASSPATH /usr/local/JSDK2.0/lib/jsdk.jar:/:/usr/local/tomcat/common/lib/servlet.jar:.
setenv OPENWINHOME /usr/openwin
setenv LD_LIBRARY_PATH /usr/openwin/lib:/opt/gnu/lib
setenv XNLSPATH /usr/local/lib/X11/X11/nls

# select java version based on JAVA_HOME
# comment out (using #) the setenv for the version you don't want 
# uncomment the one you do want. takes affect on next login

# use the next line to select java 1.0.2:
#setenv JAVA_HOME /apps/java

# use the next line to select java 1.1.4:
#setenv JAVA_HOME /apps/jdk1.1.4

#setenv JAVA_HOME /staff2/billard/jdk1.1.4

setenv JAVA_HOME /usr/local/jdk1.3.1
#/usr/local/jdk1.1.8


setenv CLASSLIB ${JAVA_HOME}/lib/classes.zip
setenv NNTPSERVER news.csu.net

if($OS == "SunOS") then
setenv MANPATH /usr/openwin/share/man:/usr/share/man:/usr/ucb/man:/usr/local/X/X11R5/man:/usr/lang/Sun-ANSI_C/man:/usr/lang/Pascal/man:/usr/lang/C++/man:/usr/local/emacs/man:/usr/local/man:/usr/local/ada/man:/usr/local/pl/man:/usr/local/sr/man

else	# This is a Solaris machine
setenv MANPATH /usr/openwin/share/man:/usr/share/man:/usr/local/man

endif

# paths common to both OS flavors
set owpath = ( /usr/openwin/bin /usr/openwin/bin/xview )
set lpath =  ( /usr/local/bin )
set xpath =  ( /usr/local/X11/bin )
#set grpath = ( ~graphics/Xsgplib/lib ~graphics/bin )
set mypath = ( ~ ~/bin )

if($OS == "SunOS") then
set lanpath = ( /usr/lang/Sun-ANSI_C /usr/lang/Pascal )
set ospath = ( /usr/ucb /bin /usr/bin /usr/etc )
set path = ($lanpath $owpath $ospath $lpath  $xpath $mypath)

else 	# This is a Solaris machine
set propath = ( /opt/opt/SUNWspro/bin )
set gnpath = ( /opt/gnu/bin )
set ospath = ( /bin /usr/ucb /usr/bin /usr/sbin /usr/ccs/bin )
set apath = (/apps/bin ${JAVA_HOME}/bin)

# $propath has to be before $ospath in order to be sure that the languages 
# are found and not trapped by the uninstalled ucb names.
# NEED TO PUT APATH BEFORE OSPATH SO THAT IT FINDS THE CORRECT JAVA. 
# THE /BIN/JAVA DOESN'T WORK

#set path = (. /staff2/billard/mysql/bin /staff2/billard/bin $propath $ospath $gnpath $owpath $apath $lpath $xpath $mypath)

set path = (. /staff2/billard/mysql/bin /staff2/billard/bin $propath $apath $ospath $gnpath $owpath $lpath $xpath $mypath / /usr/local/JSDK2.0/lib/jsdk.jar)

endif 

#setenv EXINIT 'set sh=/bin/csh sw=4 ai report=2'
#setenv MORE '-c'

#  Hook to update existing accounts.
if ( -e /usr/local/etc/acctfixes/login) then
	source /usr/local/etc/acctfixes/login
endif

#
# First check to see if this is an rlogin from an Openwindows window.
#
if($term == "sun-cmd") then
        exit	# leave terminal type unchanged
endif
	
if ( `tty` != "/dev/console" || $TERM != "sun" ) then
	# connections from modem server and non-sun workstations 
	# default to vt100
        set term=vt100
        echo "Terminal type set to vt100."
        exit
endif

#
#  Start the window system.  Give user a chance to bail out
#
set term=sun-cmd
echo -n "Starting OpenWindows (type Control-C to interrupt)"
sleep 5
# .xinitrc and .Xdefaults for OpenWindows are different than for X11.  
# Need to cp different files with X11 windowing system.  Also, change
# LD_LIBRARY_PATH to get X11 libraries instead of those for OpenWindows,
# and change path so that X11 bins selected over openwin bins.
cp .xinitrc.openwin .xinitrc
cp .Xdefaults.openwin .Xdefaults
setenv LD_LIBRARY_PATH $OPENWINHOME/lib:/usr/ucblib:/opt/gnu/lib

$OPENWINHOME/bin/openwin
clear		# get rid of annoying cursor rectangle
echo -n "Automatically logging out (type Control-C to interrupt)"
sleep 5
logout		# logout after leaving windows system